Real-Time Applications

• CGPL files with Application code and code modules.
• VoiceXML files with Application code.
• Arbitrary service files - pre-recorded media files, for example.
• Language directories.

Environments are designed to support several human (spoken) languages. The default Environment language is English. To support other languages, an Environment should contain language directories, named as the languages they support (french, russian, japanese, etc.)

A language directory can contain the same files as the Environment itself, but it cannot contain language subdirectories.

Real-Time Application Tasks can select a language to be used. When a non-default language is selected, and the application code tries to read a file from the Application Environment, the selected language subdirectory is used. If the file is not found in the language subdirectory, the file is retrieved from the Application Environment itself (i.e. the default language file is used).

The CommuniGate Pro server comes with a built-in "Stock" Real-Time Application Environment. This Environment contains some basic applications and all files required by those applications, as well as some useful code section and media files.

Each CommuniGate Pro system has its Server-wide Application Environment. A CommuniGate Pro Dynamic Cluster installation also has a Cluster-wide Application Environment. To modify these Environments, open the WebAdmin Interface Domains section and follow the PBX link.

Each CommuniGate Pro Domain has its own Application Environment. To modify that Environment, open the WebAdmin Interface Domains section, open the Domain Settings for the selected Domain and follow the PBX link.

Modifications of the Cluster-wide Environment, as well as modifications of an Environment in any Shared Domain are automatically distributed to all Cluster Members.

Since Domains have their own Application Environments, different applications in different Domains can have the same name.

All Application Environment files should use the UTF-8 character set for non-ASCII symbols.

Real-Time Application Tasks are executed "on behalf" of a certain CommuniGate Pro Account.
When an application requests an "environment file" and the default language is selected, the Server looks for the file in:

• the Account Domain Environment.
• the Server-wide Environment or (if the Account belongs to a Shared Domain) the Cluster-wide Environment.
• the Stock Environment.

If a non-default language is selected, the Server first looks for the file in the language directories of the Environments listed above. If the file is not found in any of those directories, the listed Environments themselves are searched. So, if a language-specific file has not been created, the default-language (English) file is used.

This hierarchy provides for simple Application customization. Accounts in all Domains can use the same Stock or Server-wide applications, while Domain Administrators can customize these applications by uploading custom files into their Domain Environments.

If you are uploading a file with the .sppr or the .sppi extension, the Editor assumes that the file contain some CG/PL program code, and it tries to compile that code.
If you are uploading a file with the .settings extension, the Editor assumes that the file contain a dictionary, and it tries to parse it.
If the compiler or the parser detects an error, the file is not uploaded, and the file content is displayed on the Editor page, with the red <--ERROR--> marker indicating the location of the error.

The Server places used Real-Time Environment files into an internal cache. When you upload a file to any Environment, that Environment cache is automatically cleared. If you upload a file to a Shared Domain Environment or to the Cluster-wide Environment, the updated file automatically propagates to all Cluster Members.

You can upload a set of files by uploading a TAR-archive (a file with .tar name extension). For example, when you have a TAR-archive with a predesigned Real-Time Application you can open the Environment you want to modify, and upload the .tar file. The Server will unpack the archive and store each file individually, as if they were uploaded one-by-one.

The Editor page contains the list of all Language directories:

To create a new Variant, enter the language name, and click the Create Language button.

To open a Language directory, click its name. The Editor will display the Language name, and it will provide the UP link to the list of the default language files.

CLI/API

The Command Line Interface/API can be used to manage Application Environments. See the Real-Time Application Administration section for the details.

Virtual File Storage Area

The Application Environments can be modified using FTP and HTTP clients, CG/PL applications, and any other method that provides access to the Account File Storage.
Special $DomainPXBApp, $ServerPXBApp, and $ClusterPXBApp directories provide access to the Domain and Server/Cluster-wide Application Environments.

Real-Time Applications run as Tasks. To start an Application, the CommuniGate Pro Server starts a new Task and instructs it to execute the main entry code section of the specified Application.

A Real-Time Application Task can run in the disconnected mode, or it can be a part of exactly one Real-Time session (such as a phone call) with some peer. A peer is any Real-Time entity, such as a SIP phone, a PSTN gateway, a remote Real-Time application communicating via SIP, or a local Real-Time Application, i.e. some other Task.

If a Task is participating in a session with some peer, it can be in one of the following modes:

incoming

an incoming session (a call in the telephony terms, an INVITE request in the SIP terms) has been directed to the Task, but the Task has not accepted the session (call) yet.

provisioned

an incoming session has been directed to the Task, the Task has not accepted the session yet, but it has sent a provisional response to the caller.

connecting

the Task has initiated an outgoing seesion (call), but the session has not been established yet.

connected

the Task has accepted an incoming session, or the Task has established an outgoing session.

A Task can receive Signals from its peer, and it can send Signals itself. Signals can be used to end the current session, to update the session parameters, etc. Some of the Signals sent by the peer are processed by the Real-Time Application Environment itself, while other Signals are passed to the Task for processing.

A Real-Time Application Task can have a Media Channel associated with it. When a session is established, the Task Media Channel is connected to the peer's media channel.

A Task can use its Media Channel to send media (audio, video) to the peer, and to record media sent by the peer.

A Task can switch the peer media somewhere else - for example, to a separate service providing music on hold or other media services. When the peer media is switched away, the Task Media Channel cannot be used, but the Task still can control the peer by sending Signals to it and it still receives Signals from the peer. The Task can switch the peer media back to its own Media Channel.

A Media Channel provides a conversation space. A Task can attach other peer media to the Task own Media Channel. This operation creates a conversation space (or a conference) that includes the Task own peer and all peers with media attached to this Task. Media sent by any peer in a conversation space is relayed to all other peers in that space, using the data mixing algorithms and parameters defined for that media type.

A Task with attached peer media can use its Media Channel to send media to its own peer and to all attached peers at once.

Call Transfer

The INVITE signal initiated with the REFER signal can contain authentication information. The application program can instruct the Task:

• to authenticate the INVITE signal as coming from the current Account. This is the default option.
• to authenticate the INVITE signal as coming from the peer (the entity that has sent the REFER signal).
• to reject REFER signals.

To process "Assisted" Call Transfer, the Real-Time Application engine detects all INVITE signals with the Replaces field. If the dialog data specified in the Replaces field matches an active dialog established in any Real-Time Task, the INVITE signal is directed to that Task. The Task sends a BYE signal to the current peer, and it switches its Signal dialog to the source of this INVITE signal, and it switches the Media channel to the entity specified in the INVITE signal.
This processing takes place automatically, transparently to the application program the Task is running.

Bridged Calls

• an application program some Task A is running uses the StartBridge CG/PL function to send a special [bridgeStart] event to some other Task B. The request contains the the current Task A peer media description.
• the application program the Task B is running receives this request.
• the Task B application program uses the AcceptBridge CG/PL function to build the bridge.
• the Real-Time Application engine sends a re-INVITE signal to the Task B peer, switching its Media to the Task A peer Media.
• the Real-Time Application engine sends a [bridgeResponse] event to Task A. This event contains the Task B peer media description.
• the AcceptBridge operation in Task B application program completes, and the Task B application program continues to run.
• when the Task A receives the [bridgeResponse] event, the Real-Time Application engine processes the event itself, and it does not deliver it to the Task A application program.
• the Real-Time Application engine sends a re-INVITE to the Task A peer, switching its Media to the Task B peer Media.
• the StartBridge operation in Task A completes, and the Task A application program continues to run.

When the Tasks A and B are in the "bridged" state, one of the Tasks (Task B here) can receive a re-INVITE signal from its peer. The new media description in this signal request may ask the Task to change its media parameters (hold/resume, switching to a different media source, etc.). This re-INVITE signal is processed automatically, without any involvement of the application programs the Tasks are running:

• the Real-Time Application engine sends a special [bridgeUpdate] event to the Task A. This event contains the new media description.
• the Real-Time Application engine processes the [bridgeUpdate] event itself, and it does not deliver it to the Application program the Task A is running.
• the Real-Time Application engine sends a re-INVITE signal to the Task A peer, switching it to the new Media source of the Task B peer.
• the Real-Time Application engine sends the new Peer A media dscription (received with the re-INVITE response) to the Task B as a special [bridgeResponse] event.
• when the Task B recieves the [bridgeResponse] event, the Real-Time Application engine process it itself and does not deliver it to the Task B application program.
• the new Task A media descriptor received is sent to the Peer B as a response to the initial re-INVITE signal, switching the Task B peer to the new Task A peer media.

When the Tasks A and B are in the "bridged" state, one of the Tasks (Task A here) can receive a Call Transfer (REFER) signal from its peer:

• the the Real-Time Application engine composes the INVITE signal for the Task A, and sends it to the referred peer; the Signal contains the Task B peer media description.
• the INVITE signal succeeds and the new Task A peer (peer C) media description is received.
• the Real-Time Application engine automatically sends a special [bridgeUpdate] event to the Task B, with new peer media description.
• when the Task B received the [bridgeUpdate] event, the Real-Time Application engine processes the event itself, and it does not deliver it to the Task B application program.
• the Real-Time Application engine sends a re-INVITE signal to the Task B peer, switching it to the Media source of the new Task A peer.

When the Tasks A and B are in the "bridged" state, one of the Tasks (Task A here) can receive Call Transfer (INVITE with Replaces) signal (delivered to it by the Signal module based on the Replaces field content):

• the Real-Time Application engine automatically sends a special [bridgeUpdate] event to the Task B, with new Task A peer media parameters.
• the Real-Time Application engine sends a re-INVITE signal to the Task B peer, switching it to the Media source of the Task A new peer.
• the Real-Time Application engine sends the INVITE response to the new Task A peer with the Task B peer media parameters, connecting the new Task A peer and the Task B peer media.

When the Tasks A and B are in the "bridged" state, one of the Tasks (Task A here) can decide to break the Media Bridge:

• an application program the Task A is running uses the BreakBridge CG/PL function to break the Media bridge.
• the Real-Time Application engine automatically sends a special [bridgeClose] event to the Task B, and sends a re-INVITE signal to the Task A peer, switching it to the Task A Media Channel.
• when the Task B receives the [bridgeClose] event, the Real-Time Application engine automatically sends a re-INVITE request to the Task B peer switching it to the Task B Media Channel.
• the Real-Time Application engine delivers the [bridgeClose] event to the Task B application program.

When the Tasks A and B are in the "bridged" state, one of the Tasks (Task A here) can receive a disconnect (BYE) signal from its peer, or it can quit for various reasons. In this case:

• the Real-Time Application engine automatically sends a special [bridgeClose] event to the Task B.
• when the Task B receives the [bridgeClose] event, the Real-Time Application engine automatically sends a re-INVITE request to the Task B peer switching it to the Task B Media Channel.
• the Real-Time Application engine delivers the [bridgeClose] event to the Task B application program.

The Real-Time Application engine may choose to implement a Media Bridge using one Task Media Channel as a "media relay".

B2BUAs (Back-to-Back User Agents)

Real-Time Applications can be written using the CG/PL language.

When a Task is created to process an incoming call, the main entry of the specified CG/PL application program is executed.

Real-Time Applications can use CG/PL external-declarations. When a code section (a procedure or a function) declared as external is called, a file with the code section name and the .sppi extension is loaded from the current Environment. The program code in this file must contain the code section with the specified name and of the proper type (a procedure or a function).
The program code in an .sppi file may contain other code sections as well.

Real-Time Applications can use the following built-in procedures and functions.

Input

ReadInput(timeOut)

This function is used to receive external Task communications: DTMF symbol entered by the peer, signals sent by the peer, and Events sent by other Tasks and by the system itself. See the CG/PL Events section for the detail.
The timeOut value should be a number specifying the maximum wait period (in seconds). If the timeOut value is zero, the function checks for pending digits and events, without any waiting.
The function returns:

• a string with the first DTMF symbol in the Task DTMF buffer. The symbol is removed from the Task buffer.
• a dictionary with the first waiting Event. The Event is removed from the Task Event queue.
• a null-value if no DTMF symbol and no Event was received during the specified time period.

When the peer disconnects, the Task receives a Disconnect Event from the system (this Event dictionary does not contain the .sender element).

IsDisconnectEvent(input)

This function returns a true-value if the input value is a Disconnect Event.

//
// Sample: ReadInput()
//   Accept an incoming call (stop if it's not possible).
//   Play the PressPound media file.
//   Wait for any input for up to 5 seconds.
//   If the "pound" ("#") symbol was entered,
//     play the Good media file.
//   Otherwise,
//     play the Bad media file.
//   Stop.
//
entry Main is
  if AcceptCall() != null then stop; end if;
  PlayFile("PressPound");
  PlayFile(ReadInput(5) == "#" ? "Good" : "Bad");
end entry;

Signals

RejectCall(responseCode)

This procedure rejects an incoming session if there is one: the Task should be in the incoming or provisioned mode.
The responseCode value should be a numeric value between 400 and 699. This number is sent back to the caller as the Signal Response code. If the code 401 is sent back, and the request came from outside the CommuniGate Pro Server (via the SIP protocol), the SIP server module adds the proper fields to the response to facilitate client Authentication.
The Task is placed into the disconnected mode.

AcceptCall()

This function accepts an incoming session, if there is one: the Task should be in the incoming or provisioned mode.
This function returns a null-value if the session is accepted successfully, and the Task is placed into the connected mode.
If a session cannot be accepted, this function returns an error code string, and the Task is placed into the disconnected mode.

//
// Sample: AcceptCall()/RejectCall()
//   If the current local time is not between 8:00 and 17:00,
//     reject the call (with the 403 error code) and stop.
//   Otherwise,
//     accept the call (stop if it is not possible)
//     play the Welcome media file and stop.
//
entry Main is
  currentTime = TimeOfDay(GMTToLocal(GMTTime()));
  currentHour = currentTime / 3600;
  if currentHour < 8 or currentHour >= 17 then
    RejectCall(403); stop;
  end if;
  if AcceptCall() != null then stop; end if;
  PlayFile("Welcome");
end entry;

RedirectCall(newURI)

This procedure redirects an incoming session, if there is one: the Task should be in the incoming or provisioned mode.
The newURI value should be a string, or an array of strings. The incoming session is redirected to the URI(s) specified and the Task is placed into the disconnected mode.

ForkCall(newURI)

This procedure redirects an incoming session, if there is one: the Task should be in the incoming or provisioned mode.
The newURI value should be a string, or an array of strings. The incoming session is directed to the URI(s) specified, and the current Task remains in the same state, so it can accept, reject, redirect, provision, or fork this call later.

ProvisionCall(startMedia,reliably)

This function sends a provisional Response for an incoming session Request, if there is a pending one: the Task should be in the incoming or provisioned mode.
If the startMedia value is not a null-vallue, then a Task Media Channel is created, the Task is is placed into the provisioned mode and the Media Channel operations (such as PlayFile) can be used to generate "ring-back tones".
If the reliably value is not a null-value, the response confirmation (SIP PRACK) is requested, and the Task is suspended till a confirmation request arrives.
This function returns a null-value if the response is sent successfully.
If a provisional response cannot be sent, this function returns an error code string.

SetProvisionCode(code)

This function specifies the numeric provisional Response code sent with the ProvisionCall function calls.
The code value should be a number in the 101..199 range (inclusive).
The initial provisional Response code value is 180.

//
// Sample: RedirectCall()/ProvisionCall()
//   Provision the call (stop if it is not possible).
//   If the current local time is between 12:00 and 13:00,
//     fork the call to user1 in the same domain.
//   Play the "PleaseWait" media file.
//   If the current local time is not between 8:00 and 17:00,
//     redirect the call to user2 in the same domain, and stop.
//   Otherwise,
//   Accept the call (stop if it's not possible).
//   Play the Welcome media file, and stop.
//
entry Main is
  if ProvisionCall(true,true) != null then stop; end if;
  currentTime = TimeOfDay(GMTToLocal(GMTTime()));
  currentHour = currentTime / 3600;
  if currentHour >= 12 and currentHour <= 13 then
    ForkCall("sip:user1@" + MyDomain());
    stop;
  end if;
  PlayFile("PleaseWait");
  if currentHour < 8 or currentHour >= 17 then
    RedirectCall("sip:user2@" + MyDomain());
    stop;
  end if;
  if AcceptCall() != null then stop; end if;
  PlayFile("Welcome");
end entry;

Note: if a pending incoming call has been cancelled, the Task receives a Disconnect Event, and the Task mode changes to disconnected.

SetCallParameters(parameters)

This procedure sets call (INVITE dialog) parameters.
The parameters value should be a dictionary with new call option parameters. The existing parameter values are removed.
The following parameters are used for all dialog requests:

Max-Forwards

a positive number used to limit the number of "hops" a request can traverse.

customIdentity

a string to be used as the request P-Asserted-Identity header field.

Privacy

a string or an array or string to be used as the request Privacy header field.

IPSource

the IP Address object that overrides the Server rules and explicitly sets the source IP Address for outoging SIP packets and locally generated media.

The following parameters are used when a call dialog is established:

Session-Expires

a non-negative number specifying the default session expiration (dialog refreshing) time period. If set to zero, no dialog refreshing takes place.

Some parameters are used when a call is initiated (with the StartCall, StartBridgedCall functions) or when a call is accepted (with the AcceptCall function) - see below.

StartCall(destination)

This function initiates an outgoing session. The Task should be in the disconnected mode.
The destination value should be a string containing the URI to send a session request to, or a dictionary containing the following string elements:

"" (empty string)

the URI to send the request to.

From (optional)

an E-mail, URI, or field-data to use for the request From field. If not specified, the current Account data is used.

To (optional)

an E-mail, URI, or field-data to use for the request To field. If not specified, the request URI is used.

Call-ID (optional)

a string to use for the request Call-ID field. If not specified, a new Call-ID is generated.

The following optional parameters are taken from the destination dictionary. If they are absent (or the destination is not a dictionary), they are taken from the current call parameters set with the SetCallParameters procedure:

Expires

a number specifying the maximum calling (alerting) time (in seconds).

Subject

request Subject string.

Remote-Party-Id

a dictionary to compose the request Remote-Party-Id field.

Privacy

a string to compose the request Privacy field.

Diversion

an array to compose the request Diversion fields.

P-CGP-Private

a string to compose the request P-CGP-Private field. This field can be used to pass arbitrary parameters between sending and receiving Tasks (on the same or different systems).

P-CGP-Local

a string to compose the request P-CGP-Local field. This field can be used to pass arbitrary parameters between sending and receiving Tasks (only within the same single-server or Cluster systems).

Call-Info

an array to compose the request Call-Info fields.

Replaces

a string or a dictionary to compose the request Replaces field. If a dictionary is used, it should contain the string values Call-ID, fromTag, toTag, and a boolean value early-only.

NoInitSDP

if this parameter is specified, the call establishment request does not contain the local Media channel SDP.

mediaRelay

if this parameter is specified, a Media Proxy is always created for the call.

This function returns an error code string if an outgoing call cannot be initiated.
If an outgoing call has been initiated successfully, the function returns a null-value, and the Task starts to receive call progress Events from the system: zero or more provisional response Events, followed by exactly one final response Event.
If the outgoing session has been established successfully, the Task receives a final response Event without a parameter.
If the outgoing session has not been established, the Task receives a final response Event with a parameter - the error code string.

IsCallProvisionEvent(input)

This function returns a true-value if the input value is a call provisional response Event. Otherwise the function returns a null-value.

IsCallCompletedEvent(input)

This function returns a true-value if the input value is a call final response Event. Otherwise the function returns a null-value. When a Task receives a final response Event, the call signaling process has completed. If the Event has a parameter, the call has failed, and the parameter contains the error code string.

CancelCall()

If a Task has a pending outoging call (initiated using the StartCall function), this procedure cancels that call (the Task will not receive a final response Event).

Disconnect()

This procedure ends the active session, if any, and the Task is placed into the disconnected mode.

//
// Sample: StartCall()/Disconnect()
//   Accept an incoming call (stop if it's not possible).
//   Remember the caller URI.
//   Play the CallBack media file.
//   Disconnect();
//   Call the caller back (stop if it's not possible).
//   Play the IamBack media file, and stop.
//
entry Main is
  if AcceptCall() != null then stop; end if;
  fromWhom = RemoteURI();
  PlayFile("CallBack");
  Disconnect();

  if StartCall(fromWhom) != null then stop; end if;

  loop
    input = ReadInput(3600);
  exitif not IsCallProvisionEvent(input);
    null;
  end loop;

  if not IsCallCompletedEvent(input) or else
     input.parameter != null then stop; end if;

  PlayFile("IamBack");
end entry;

IsConnected()

This function returns a true-value if the Task is in the connected mode.

IsHalfConnected()

This function returns a true-value if the Task is in the connected or provisioned mode.

PendingRequestData(fieldName)

This function returns a data element of the pending incoming request.
If a request is pending, the function returns the following data, depending on the fieldName value, which should be a string:

Call-ID

the function returns a string with the request Call-ID value.

From, To, Remote-Party-Id

the function returns a dictionary if the field exists in the request. The dictionary contains the following elements:

"" (and element with empty string key)

the address (in the username@domain form)

@realName

a string with the "display-name" part of the address

tag

the "tag" URI parameter

@uri-params

a dictionary with other URI parameters.

All elements except the address element are optional.

Route, Record-Route, Diversion, Via, Path, Supported, Require, Proxy-Require, Privacy

the function returns an array containing one or more strings with field values. If no field value exists, the function returns a null-value.

CSeq

the function returns a number - the value of the CSeq field numeric part.

Max-Forwards

the function returns a number - the value of the Max-Forwards field.

User-Agent, Reason, Privacy, P-CGP-Private, P-CGP-Local

the function returns a string - the field value. If the field is absent, the function returns a null-value.

Accept

the function returns an array containing 2 strings for each field value: the accepted content type and the accepted content subtype. If the field is absent, the function returns a null-value.

Foreign-Asserted-Identity

the function returns an array containing one dictionary for each request P-Asserted-Identity field. Each dictionary contains the same elements as the From field dictionary.

If no request is pending, the function returns a null-value.

PendingRequestExData(fieldName)

This function returns a non-standard data element of the pending incoming request.
The fieldName value should be a string. It specifies the name of a non-standard request field.
If a request is pending, the functions returns the a string containing the specified request field data.
If no request is pending, the function returns a null-value.

SetForeignCredentials(authName,password)

This procedure sets the credentials (the authenticated name and password) to be used with outgoing requests sent with this this Task.
The authName and password values should be strings, otherwise the credentials are reset.

SetReferMode(mode)

This procedure is used to specify how the Task processes the REFER requests and INVITE/replaces requests. The mode parameter should be a string:

self

authenticate outgoing signals as coming from the current Account

peer

authenticate outgoing signals as coming from the Task peer (i.e. the sender of the REFER signal)

any other value

prohibit REFER and INVITE/replaces request processing

SetTransferReportMode(mode)

This function sets the function flag for call transfer reporting.
If the mode value is a null-value, no event is sent when a Task is transferred to a different peer.
Otherwise, the Task receives a special CallTransferred Event when it is transferred to a different peer.
The function returns the previous value of this function flag.
When a new Task is created, its call transfer reporting is disabled (the function flag is set to a null-value).

IsCallTransferredEvent(input)

This function returns a true-value if the input value is a CallTransferred Event. Otherwise the function returns a null-value.

SetBridgeBreakMode(mode)

This procedure is used to specify how the Task reacts when a media bridge is broken by the other task. The mode parameter should be a string:

disconnect

the BYE signal is sent to the Task peer, and the Task enters the disconnected mode.

keep

if the Task does not have a Media channel, it is created, and the Task peer is switched to that channel.

Dialog

RemoteURI()

This function returns a string with the peer URI (taken from the dialog From/To addresses). If there is no session in place, the function returns a null-value.

LocalURI()

This function returns a string with the Task URI.

IncomingRequestURI()

This function returns a string with URI of the pending incoming INVITE request. If there is no pending incoming INVITE request, the function returns a null-value.

RouteLocalURI(uri)

This function tries to Route the E-mail address from the specified URI. If the URI cannot be parsed, or the URI address cannot be routed, or it routes to a non-local address (i.e an E-mail address hosted on a different system), this function returns a null-value. Otherwise, the function returns the E-mail address of the CommuniGate Pro user the original URI address is routed to.
This function allows you to correctly process all Forwarders, Aliases, and other CommuniGate Pro Routing methods.

RemoteIPAddress()

This function returns an ip-address object the session establishment request was received from or was sent to. This IP Address/port pair is the actual peer address or the address of a proxy used to relay the peer signaling.

RemoteAuthentication()

This function returns a null-value if the session starting request was not authenticated, or a string with the authenticated user E-mail address.

DTMF

//
// Sample: ReadInput()/SendDTMF()
//   Accept an incoming call (stop if it's not possible).
//   Wait for an input for 10 seconds. If no input - stop.
//   If a digit is entered
//      play that digit, and send it back.
//      (using "0" ... "9" files)
//   If a star ("*") is entered,
//     wait for a digit (for 3 seconds)
//     and play the digit number square (2 digits)
//   If a pound ("#") is entered or the Peer
//     has disconnected, or any Event was sent, stop.
//
entry Main is
  if AcceptCall() != null then stop; end if;
  loop
    input = ReadInput(10);
	if input == "*" then
	  input = ReadInput(3);
	  if IsString(input) and input != "#" then
	    input = "*" + input;
	  end if;
	end if;
  exitif not IsString(input) or input == "#";
    if Substring(input,0,1) != "*" then
	  PlayFile(input);
	  void(SendDTMF(input));
	else
	  input = Number(Substring(input,1,1);
	  product = input *  input;
	  PlayFile(String(product/10));
	  PlayFile(String(product%10));
	end if;
  end loop;
end entry;

Media

PlayFile(fileName)

This procedure retrieves a file from its Application Environment and plays it. The string parameter fileName specifies the file name. If the specified file name does not contain a file name extension, supported extensions are added and tried.
The file should contain media data in one of the supported formats.
Playing is suppressed or interrupted if the session ends, if the DTMF buffer is not empty (unless DTMF Interruption is disabled), or if there is an Event enqueued for this Task.

PlayFileInLoop(fileName,msec)

This procedure is similar to the PlayFile procedure.
The msec parameter value should be a number.
This procedure plays the specified file for msec milliseconds, repeating file in a loop if the file media playing period is shorter than the specified period. If the msec parameter has a negative value, the file is played in a loop without a predefined time limit.
Playing is suppressed or interrupted if the session ends, if the DTMF buffer is not empty (unless DTMF Interruption is disabled), or if there is an Event enqueued for this Task.

Play(waveData)

This procedure plays the waveData value which should be a datablock.
The datablock should contain media data in one of the supported formats.
Playing is suppressed or interrupted if the session ends, if the DTMF buffer is not empty (unless DTMF Interruption is disabled), or if there is an Event enqueued for this Task.

PlayInLoop(waveData,msec)

This procedure is the same as the Play procedure, but it can play the media data in a loop, in the same way as the PlayFileInLoop procedure does.

GetPlayPosition()

This function returns a number - the portion of the media (in milliseconds) played by the last PlayFile, PlayFileInLoop, Play, PlayInLoop operation.
If the media was played in a loop, the length of the played portion in the last "loop" is returned: if a 3-second sound was played in loop, and it was interrupted after 7.2 seconds, the function returns 1200.
If the last Play* operation did not play its sound (because the DTMF buffer was not empty or there was an enqueued Event), the function returns either 0, or a negative value.

SetPlayPosition(arg)

This procedure instructs the very next Play* operation to start playing its sound not from its beginning.
The arg value should be a non-negative number. It specifies how many milliseconds of the media should be skipped before the Play* operation starts to play the media.

IsPlayCompleted()

This function returns a true-value if the media played by the last Play* operation was played in full. If media playing was interrupted, the function returns a null-value.

Record(timeLimit)

This function records incoming audio data. The timeLimit value should be a positive number, it specifies the maximum recording time in seconds.
Recording is suppressed or interrupted if the session ends, if the DTMF buffer is not empty, or if there is an Event enqueued for this Task.
The function returns a null-value if recording was suppressed, or a datablock with the recorded sound in the WAV format.

SetLocalHold(flag)

This procedure sets the current call "on Hold" (if the flag is a true-value), or releases the call from hold (if the flag is a null-value).
This procedure can be used only when the Task is in the connected mode, and the Task peer media is not bridged.

ReleaseMediaChannel()

This procedure releases the Task Media Channel (releasing the associated system resources).
This procedure can be used only when the Task is in the disconnected mode, or when the Task peer media is bridged.

//
// Sample: Record()/PlayFile()/Play()
//   Accept an incoming call (stop if it's not possible).
//   Play the GreetingIs file.
//   Read the current prompt from
//      the MyGreeting.wav file in the Personal Site.
//   Loop playing the greeting.
//      if "1" is entered, rewrite the prompt file and quit
//      if "2" is entered, play "Beep" and record the prompt.
//
entry Main is
  if AcceptCall() != null then stop; end if;
  PlayFile("GreetingIs");
  prompt = ReadSiteFile("MyGreeting.wav");
  loop
    if IsData(prompt) then Play(prompt); end if;
    input = ReadInput(10);
  exitif not IsString(input) or else input == "#";
    if input == "1" then
	  if WriteSiteFile("MyGreeting.wav",prompt) then
	    PlayFile("Goodbye"); stop;
	  end if;
	  PlayFile("Failure");
	elif input == "2" then
	  PlayFile("Beep");
	  prompt = Record(30);
	else
	  PlayFile("InvalidEntry");
	end if;
  end loop;
  PlayFile("GoodBye");
end entry;

Bridges and Mixers

//
// Sample: StartBridge()/AcceptBridge()/BreakBridge()
//   Accept an incoming call (stop if it's not possible).
//   Create a new Task to run the Caller code,
//     and send it an Event with the URI to dial.
//   Play the PleaseWait media file.
//   Wait for a StartBridge Event from the Caller Task.
//   Accept it and loop till the user disconnects.
//
//   The Caller code:
//   Receive a URI to call as an Event from the parent Task
//   Connect to the URI and play the YouGotACall media file
//   StartBridge with the parent, loop till the user disconnects
//
entry Caller forward;
procedure ControlBridge() forward;

entry Main is
  if AcceptCall() != null then stop; end if;

  callerTask = spawn Caller;
  if callerTask == null or else
     SendEvent(callerTask,"dial","sip:internal@partner.dom") != null then
	PlayFile("Failure");
	stop;
  end if;

  PlayFile("PleaseWait");
  input = ReadInput(30);
  if not IsStartBridgeEvent(input) or else
     AcceptBridge(input) != null then
	PlayFile("Failure");
	stop;
  end if;

  // we have established a bridge
  ControlBridge();
  PlayFile("GoodBye");
end entry;

//
// Caller Task code
//
entry Caller is
  // wait for a "dial" event from the main task
  input = ReadInput(30);
  if input == null or input.what != "dial" then stop; end if;

  mainTask = input.sender;

  // Calling the URI specified as the Event parameter
  // If connection failed, send an Event back to the
  //  main task and quit 
  resultCode = StartCall(startEvent.parameter);
  if resultCode != null then
    void(SendEvent(mainTask,"result",resultCode));
	stop;
  end if;

  // wait for any Event other than provisional ones
  loop
    input = ReadInput(3600);
  exitif not IsCallProvisionEvent(input);
  end loop;

  // the parent has sent us "stop" - then we'll die immediately
  if IsDictionary(input) and then input.what == "stop" then stop; end if;
  
  if not IsCallCompletedEvent(input) or else input.parameter != null then
    void(SendEvent(mainTask,"result","generic error"));
	stop;
  end if;

  if StartBridge(mainTask) != null then
	PlayFile("Failure");
	stop;
  end if;

  // we have established a bridge
  ControlBridge();
  PlayFile("GoodBye");
end entry;

//
// Controlling the peer signaling:
// while the media is bridged:
//	exit if the peer hangs up, dials "#"
//  or if the bridge is removed
//  
procedure ControlBridge() is
  loop
    input = ReadInput(3600);
  exitif IsBreakBridgeEvent(input) or else 
          IsDisconnectEvent(input) or else input == "#";
  end loop;
  void(BreakBridge());
end procedure;

Call Transfer

Info Requests

Service Requests